La secuencia de Beatty para Pi

La secuencia de Beatty para Pi


¿Sabías que puedes usar π para dividir los números enteros positivos en dos grupos separados? No es dificil. Un grupo es generado por las partes enteras de múltiplos de π. La función FLOOR devuelve la parte entera de un número positivo, por lo que puede escribir enteros generados a partir de π como Bnorte = {piso(n*π)} para n=1,2,3,…. Esto se llama el Secuencia hermosa para π. Los primeros números en la secuencia de Beatty para π son 3, 6, 9, 12, 15, 18, 21, 25, 28, 31, 34, 37, 40, 43, 47, 50, 53,….

El segundo grupo contiene todos los enteros positivos que no están en la secuencia de Beatty: 1, 2, 4, 5, 7, 8, 10, 11, 13, 14, 16, 17, 19, 20, 22, 23, 24, 26 , …. ¡Un hecho notable es que el segundo grupo de enteros también es la secuencia de Beatty para un número! De hecho, es la sucesión de Beatty para el número π/(π-1). Por lo tanto, los números enteros positivos se dividen en dos grupos distintos utilizando la secuencia de Beatty para π y la secuencia de Beatty complementaria para π/(π-1). Todas estas dos secuencias producen números enteros positivos, y ninguna secuencia contiene un número entero. Por ejemplo, el número 2020 aparece solo en la secuencia de Beatty para π, mientras que 2022 aparece en la secuencia complementaria.

Resulta que las únicas propiedades de π necesarias para este resultado son el hecho de que π es irracional y π > 1, un resultado conocido como teorema de Beatty. Este artículo utiliza SAS para ilustrar la secuencia de Beatty para π y su secuencia complementaria.

La secuencia de Beatty

Por cada número irracional R > 1, el episodio de Beatty para R es una parte entera de la sucesión r, 2*r, 3*r, …. Puedes calcular la sucesión de Beatty como Bnorte = {piso(n*r)} para n=1,2,3,…. El secuencia complementaria es generado por el número irracional C = R/(R-1) de la misma manera. La secuencia complementaria es Cnorte = {piso(n*c)} para n=1,2,3,….

Con estas definiciones, el teorema de Beatty (también llamado teorema de Rayleigh) establece que para todo número irracional R > 1, la secuencia de Beatty y la secuencia del complemento son disjuntas y producen todos los números enteros positivos. Para cualquier entero positivo jcualquiera j es un elemento de la secuencia de Beatty o j es un elemento de la secuencia complementaria. Así, la secuencia de Beatty y su secuencia complementaria dividen los números enteros en dos partes separadas.

Para una prueba formal, consulte el artículo de Wikipedia o el excelente sitio web Cut the Knot.

La secuencia de Beatty para Pi

Ilustremos la oración usando R = π y un número finito de enteros positivos. El siguiente ejemplo usa los primeros 355 términos de las secuencias de Beatty y complemento que cubren los primeros 520 enteros positivos. ¿Por qué 355 términos? Porque 355/113 es parte de la expansión en fracción continua de π y es una excelente aproximación a π.

Primero, visualicemos cada secuencia. Cada secuencia es una restricción de fila a los enteros positivos. La secuencia Beatty Bnorte = {piso(π n)} resulta de la recta que pasa por el origen con pendiente π; la secuencia complementaria Cnorte se obtiene de la recta con pendiente π/(π – 1) ≈ 1.4669… El siguiente paso de SAS DATA genera valores para cada secuencia y luego ordena los valores de secuencia. Los valores se presentan gráficamente y codificados por colores según pertenezcan a la secuencia de Beatty (‘B’) o a la secuencia del complemento (‘C’).

%let maxN = 355;            /* because pi ~ 355/113 */
data Beatty;
pi = constant('pi');
Sequence = 'B';             /* slope = pi */
do n = 1 to &maxN;
   s = floor(pi*n);         /* the Beatty sequence */
   output;
end;
Sequence = 'C';             /* slope = pi/(pi-1) */
do n = 1 to &maxN;
   s = floor(pi/(pi-1)*n);  /* the complementary sequence */
   output;
end;
/* find the lessor of the maximum values of the sequences */
MB = floor(pi* &maxN);
MC = floor(pi/(pi-1)* &maxN);         
call symputx('maxS', min(MB, MC));    /* for maxN=355, maxS=520 */
drop MB MC pi;
run;
 
%put &=maxS;   /* display value in SAS log */
proc sort data=Beatty;
   by s;
run;
 
ods graphics / width=400px height=560px;
title "Beatty and Complementary Sequences for pi";
proc sgplot data=Beatty;
   scatter x=n y=s / group=Sequence markerattrs=(symbol=CircleFilled);
   xaxis grid;
   yaxis max=&maxS grid LABEL="Sequence Value";
run;

La línea roja tiene una pendiente de π y la línea azul tiene una pendiente de π/(π-1). El dominio de estas funciones contiene los enteros en [1, 355]. El área de la línea roja es la secuencia de Beatty para π; el área de la línea azul es la secuencia complementaria.

Debido a la escala, es difícil determinar cómo se entrelaza el rango de las dos funciones lineales. Imprimamos algunos valores de las secuencias entrelazadas:

proc print data=Beatty(obs=12) noobs;
   var s Sequence;
run;

El resultado muestra que los primeros dos enteros son de la secuencia del complemento, mientras que el tercero es de la secuencia de Beatty para π. Llamo a esto el patrón «dos afuera, uno adentro». Este patrón continúa durante las primeras 12 observaciones. Bueno, por supuesto, este patrón no puede continuar para siempre, de lo contrario, 1/3 de los números enteros positivos estarían en la secuencia de Beatty. Sin embargo, sabemos que (1/π)ésimas partes de los números enteros pertenecen a la sucesión de Beatty considerando el límite de la razón norte/Bnorte como norte → ∞. Por lo tanto, un poco menos de 1/3 de los números enteros están en la secuencia de Beatty. Grafiquemos los primeros 60 enteros positivos y visualicemos si cada entero pertenece a la secuencia de Beatty o a la secuencia del complemento, así:

data SeqViz;
set Beatty(where=(s<=60));
z = 1;     /* for plotting the points as a strip plot */
run;
 
ods graphics / width=640px height=150px;
title "Beatty and Complementary Sequences for pi";
title2 "First 60 Integers";
proc sgplot data=SeqViz noautolegend;
   where s<=60;
   yaxis display=none;
   xaxis grid gridattrs=(color=CXF0F0F0) values=( 0 to 21 by 3
                      25 to 43 by 3
                      47 to 60 by 3 ) valueshint;
   scatter x=s y=z / group=Sequence datalabel=Sequence
           datalabelpos=top datalabelattrs=(size=12)
           markerattrs=(symbol=SquareFilled size=12);
run;

El gráfico muestra que de vez en cuando hay tres (en lugar de dos) elementos consecutivos de la secuencia complementaria. Esto sucede primero para los números enteros 22, 23 y 24. El hecho de que el elemento «extra» de la secuencia del complemento aparezca en 22 no es una coincidencia. Esto se debe a que 22/7 es una buena aproximación de π. A partir de entonces, el patrón vuelve a ser «dos afuera, uno adentro» hasta el siguiente múltiplo de 22, que es 44, cuando otro triplete de enteros pertenece a la secuencia complementaria.

El patrón diverge nuevamente para otros numeradores asociados con la expansión continua de fracción de π, como B 355/113. El siguiente diagrama muestra la pertenencia de los enteros en el rango [302, 361]. Los dos fuera, uno dentro del patrón se rompe en 308 = 22*14 y en 330=22*15, pero luego el patrón vuelve a divergir en 355, que no es un múltiplo de 22.

Compruebe que las secuencias de Beatty y complemento son disjuntas

Hemos afirmado que las sucesiones de Beatty y del complemento son disjuntas y que su unión es el conjunto de todos los enteros positivos. No puede probar este hecho con cálculos numéricos, pero puede comprobar que se cumple para el conjunto finito de números que generamos. El siguiente programa SAS/IML comprueba que las dos secuencias no se cruzan y que su unión cubre todos los enteros positivos (hasta 520).

/* Check union and intersection properties of Beatty and complementary sequences */
proc iml;
use Beatty;
   read all var 's' into B where(Sequence='B');
   read all var 's' into C where(Sequence='C');
close;
 
/* is there any intersection? */
intersect = xsect(B, C);
if IsEmpty(intersect) then 
   print "B and C do not intersect";
else print "The intersection is:", intersect;
 
/* use the UNION function */
max = min( max(B), max(C) );
union = union(B, C);
union = union[ , 1:max];  /* only test for values in [1, max] */
if all(union = 1:max) then 
   print "All integers are found";
else 
   print "Some integer is missing";
QUIT;

El programa verifica (para enteros positivos menores de 520) que las secuencias de Beatty y del complemento no se cruzan. Además, todo número entero es un elemento de la secuencia de Beatty para π o un elemento de la secuencia del complemento.

Quiero señalar una sintaxis genial de SAS/IML: la declaración IF-THEN se puede usar para probar si un vector es igual a otro vector. En el programa la declaración
todos (unión = 1:max) devuelve verdadero, es cada elemento del vector Unión es igual al elemento correspondiente del vector {1,2,3,…,max}.

Resumen

Este artículo describe el teorema de Beatty, que es un resultado interesante en matemáticas. Dado un número irracional R > 1, el episodio de Beatty para R y la secuencia complementaria divide los enteros positivos en dos grupos disjuntos: la secuencia de Beatty para R y la secuencia complementaria. El artículo ilustra el teorema usando R = π y muestra algunas conexiones con la expansión en fracción continua de π.

Related post

Una guía completa para la gestión de las relaciones con los clientes

Una guía completa para la gestión de las relaciones…

Cuando se trata de administrar un negocio, una de las cosas más importantes es mantener contentos a sus clientes. No hay…
La clave para la protección climática puede ser el alivio de la deuda

La clave para la protección climática puede ser el…

Debería quedar bastante claro para todos que resolver los desafíos climáticos de un planeta sobrecalentado requerirá la cooperación entre todas las…
El aprendizaje automático se encuentra con los dedos, las manos y los codos para mejorar la terapia robótica

El aprendizaje automático se encuentra con los dedos, las…

25 de junio de 2022 (Noticias de Nanowerk) Los accidentes cerebrovasculares y las lesiones de la médula espinal dejan a millones…

Leave a Reply

Tu dirección de correo electrónico no será publicada.