Estimaciones de Bootstrap para modelos de regresión no lineal en SAS

Estimaciones de Bootstrap para modelos de regresión no lineal en SAS


En The Essential Guide to Bootstrapping in SAS, observo que existen muchas técnicas de SAS que admiten la estimación de bootstrap sin que el analista tenga que escribir un programa. Anteriormente escribí sobre el uso de opciones de arranque en el procedimiento TTEST. Este artículo describe el procedimiento NLIN, que puede ajustar modelos no lineales a los datos mediante un método de mínimos cuadrados. El procedimiento NLIN admite la instrucción BOOTSTRAP, que le permite calcular estimaciones de arranque de los parámetros del modelo. En los modelos no lineales, la distribución de muestreo de una estimación de regresión a menudo no es normal, por lo que los intervalos de confianza de arranque pueden ser más útiles que los intervalos de confianza tradicionales de Wald, que suponen que las estimaciones se distribuyen normalmente.

Datos para una curva dosis-respuesta

La documentación de PROC NLIN incluye un ejemplo de ajuste de una curva dosis-respuesta paramétrica a los datos. El ejemplo solo tiene siete observaciones, pero hice siete observaciones adicionales (falsas) para enriquecer el ejemplo. El gráfico de la derecha visualiza los datos y una curva dosis-respuesta paramétrica ajustada con PROC NLIN. La curva representa el valor esperado del modelo log-logístico


(f(x) = delta + frac{alpha – delta }{1+gamma exp left{ beta ln (x)right} })
Donde X es la dosis. Se supone que la respuesta está limitada en el intervalo [δ, α]donde δ es la respuesta para X=0, y α es el límite de la respuesta como X → ∞. Los parámetros β y γ determinan la forma de la curva dosis-respuesta. En el siguiente ejemplo, δ=0 y los datos sugieren que α ≈ 100.

El gráfico de la derecha muestra los datos y la curva dosis-respuesta que mejor se ajusta a estos datos en un sentido de mínimos cuadrados.

El siguiente paso DATA define los datos. Llamar a PROC NLIN especifica el modelo y produce la gráfica y la tabla con estimaciones de parámetros y la correlación entre los parámetros de regresión:

data DoseResponse;
   input dose y @@;
   logdose = log(dose);
datalines;
0.009   96.56   0.035   94.12   0.07    89.76
0.15    60.21   0.20    39.95   0.28    21.88
0.50     7.46   0.01    98.1    0.05    90.2
0.10    83.6    0.15    55.1    0.30    32.5
0.40    12.8    0.45     9.6
;
 
proc nlin data=DoseResponse plots(stats=none)=(fitplot); /* request the fit plot */
   parameters alpha=100 beta=3 gamma=300;                /* three parameter model */
   delta = 0;                                            /* a constant; not a parameter */
   Switch = 1/(1+gamma*exp(beta*log(dose)));             /* log-logistic function */
   model y = delta + (alpha - delta)*Switch;
run;

Vea estadísticas de errores estándar, intervalos de confianza (IC) y correlación de parámetros. Tenga en cuenta que estas columnas contienen la palabra «sobre» (o «aproximadamente») en los títulos de las columnas. Esto se debe a que estas estadísticas se calculan utilizando fórmulas de modelos de regresión lineal. Bajo los supuestos de la regresión lineal ordinaria, las estimaciones de los coeficientes de regresión se distribuyen (asintóticamente) de acuerdo con una distribución normal multivariante. Con los modelos de regresión no lineal, no conoce de antemano la distribución de muestreo de las estimaciones de los parámetros. Sin embargo, puede utilizar métodos de arranque para examinar la distribución de muestreo y mejorar las estimaciones del error estándar, los intervalos de confianza y la correlación de los parámetros.

La instrucción BOOTSTRAP en PROC NLIN

Puede iniciar manualmente, pero PROC NLIN admite la instrucción BOOTSTRAP, que inicia automáticamente los coeficientes de regresión. La instrucción BOOTSTRAP admite las siguientes opciones:

  • Utilice la opción SEED= para especificar el flujo de números aleatorios.
  • Use la opción NSAMPLES= para especificar la cantidad de muestras de arranque que desea usar para inferir. Sugiero al menos 1000, y 5000 o 10000 son mejores valores.
  • Utilice la opción BOOTCI para solicitar intervalos de confianza de arranque para los parámetros de regresión. Puede utilizar la subopción BOOTCI(BC) para solicitar el método corregido y ajustado sistemáticamente. Utilice la opción BOOTCI(PERC) para los intervalos de confianza tradicionales basados ​​en percentiles. Recomiendo la opción de corrección de sesgo, que es la configuración predeterminada.
  • Utilice la opción BOOTCOV para mostrar una tabla que muestre la covarianza estimada entre parámetros.
  • Utilice la opción BOOTPLOTS para crear histogramas de las estadísticas de arranque para cada parámetro de regresión.

La siguiente llamada a PROC NLIN repite el análisis anterior, pero esta vez solicita un análisis de arranque para mejorar las estimaciones de errores estándar, IC y covarianza entre parámetros:

proc nlin data=DoseResponse plots(stats=none)=(fitplot); /* request the fit plot */
   parameters alpha=100 beta=3 gamma=300;                /* three parameter model */
   delta = 0;                                            /* a constant; not a parameter */
   Switch = 1/(1+gamma*exp(beta*log(dose)));             /* log-logistic function */
   model y = delta + (alpha - delta)*Switch;
   BOOTSTRAP / seed=12345 nsamples=5000 bootci(/*BC*/) bootcov bootplots;
run;
run;

La tabla de estimaciones de parámetros es el resultado más importante, ya que muestra las estimaciones de arranque para el error estándar y los IC. Con estos datos, puede ver que las estimaciones de los parámetros alfa y beta no son muy diferentes de las estimaciones aproximadas. Sin embargo, las estimaciones del parámetro gamma son bastante diferentes. El error estándar de arranque es casi 2 unidades más ancho. El intervalo de confianza corregido por sesgo de arranque es aproximadamente 5 unidades más corto y desplazado hacia la derecha en comparación con la IA tradicional.

Puede examinar la distribución de arranque del parámetro gamma para comprender las diferencias. El siguiente histograma es creado automáticamente por PROC NLIN porque usamos la opción BOOTPLOTS. Puede ver que la distribución de las estimaciones gamma no es normal. Muestra un nivel moderado de asimetría positiva y curtosis. Por lo tanto, las estimaciones de bootstrap difieren significativamente de las estimaciones tradicionales.

Las distribuciones de las estadísticas alfa y beta no se muestran, pero muestran poca desviación de la normalidad. Por lo tanto, las estimaciones de bootstrap para los parámetros alfa y beta no son muy diferentes de las estimaciones tradicionales.

No muestro las estimaciones de arranque de la covarianza de los parámetros. Sin embargo, si convierte las estimaciones de covarianza de bootstrap en una matriz de correlación, encontrará que las estimaciones de bootstrap están cerca de las estimaciones aproximadas que se muestran anteriormente.

resumen

La declaración BOOTSTRAP en PROC NLIN simplifica la realización de un análisis de arranque de las estimaciones de regresión para un modelo de regresión no lineal. La instrucción BOOTSTRAP arranca automáticamente las estimaciones del error estándar, los intervalos de confianza y la covarianza de los parámetros. Además, puede utilizar la opción BOOTPLOTS para visualizar la distribución de arranque de las estimaciones. Como se muestra en este ejemplo, a veces la distribución de la estimación de un parámetro no es normal, por lo que el análisis de arranque proporciona mejores estadísticas inferenciales para el análisis de regresión.

Related post

Los investigadores están desarrollando tintas de nanotecnología para la bioelectrónica portátil imprimible en 3D

Los investigadores están desarrollando tintas de nanotecnología para la…

18 de agosto de 2022 (Noticias de Nanowerk) La electrónica flexible ha permitido el diseño de sensores, actuadores, microfluidos y electrónica…
Informe: Los nuevos modelos de gestión de datos son esenciales para operar en la nube

Informe: Los nuevos modelos de gestión de datos son…

A medida que las organizaciones adoptan cada vez más los principios de la nube primero y la cantidad y variedad de…
Los accionistas son fundamentales para que Amazon rinda cuentas sobre cuestiones de sostenibilidad

Los accionistas son fundamentales para que Amazon rinda cuentas…

Si bien se abandonaron las 15 resoluciones respaldadas por inversores presentadas durante la reciente reunión de accionistas de Amazon, al menos…

Leave a Reply

Tu dirección de correo electrónico no será publicada.